1 PRINT "JUEGO VIAJE A LAS ESTRELLAS DE LA UNIV. DE TEXAS POR GRADY HICKS Y JIM KORP."
2 PRINT "IDEA GENERAL ROBADA A LA UNIV. PENN. POR HICKS."
3 PRINT "MUY MEJORADO, Y ADAPTADO A TAURUS POR KORP, 5 ABRIL 73."
4 GOSUB 9980
5 PRINT " TENGA CUIDADO Y PASE UN BUEN MOMENTO."
6 PRINT
7 PRINT
8 X8=RND(0)
9 DIM Q$(10)
10 DIM G(8,8),Q(8,8),D(8),K(9,3),N(3)
11 DIM C$(20)
12 GOSUB 8050
13 PRINT " PARA JUGAR VERSION CORTA, PRESIONE 1 ---"
14 PRINT " PARA JUGAR VERSION REGULAR, PRESIONE 2:";
15 INPUT V
16 IF V = 1 THEN 20
17 IF V = 2 THEN 20
18 PRINT
19 GOTO 13
20 T0=INT(RND(0)*20+20)*100
21 T=T0
22 T9=40
23 E0=3000
24 E=3000
25 P0=10
26 P=10
27 S9=200
29 GOSUB 8200
30 DEF FNO(F)=SQR((K(F,1)-S1)^2+(K(F,2)-S2)^2)
32 Q1=INT(RND(0)*8+1)
34 Q2=INT(RND(0)*8+1)
35 F=1
40 FOR I=1 TO 7
42 D(I)=0
44 NEXT I
62 S1=INT(RND(0)*8+1)
64 S2=INT(RND(0)*8+1)
65 DIM F$(12)
66 DIM N$(15)
72 REM: SET UP GALAXY
75 B9=0
76 LET E4=W3=A9=C5=0
77 Z$="DOWN"
80 K9=0
85 FOR I=1 TO 8
90 FOR J=1 TO 8
91 R=RND(0)*64
95 IF V=2 THEN 150
100 T9=20
110 IF R>=.28 THEN 114
111 K3=4
112 GOTO 135
114 IF R>=1.78 THEN 118
115 K3=3
116 GOTO 135
118 IF R>=5.28 THEN 122
119 K3=2
120 GOTO 135
122 IF R>=9.28 THEN 130
123 K3=1
124 GOTO 135
130 K3=0
135 K9=K9+K3
145 GOTO 206
150 REM: DETERMINA CANTIDAD DE KLINGONS, BASES Y ESTRELLAS.
152 IF R>=.01 THEN 156
153 K3=9
154 GOTO 195
156 IF R>=.10 THEN 160
157 K3=8
158 GOTO 195
160 IF R>=.30 THEN 164
161 K3=7
162 GOTO 195
164 IF R>=.80 THEN 168
165 K3=6
166 GOTO 195
168 IF R>=1.25 THEN 172
169 K3=5
170 GOTO 195
172 IF R>=2.00 THEN 176
173 K3=4
174 GOTO 195
176 IF R>=5.28 THEN 180
177 K3=3
178 GOTO 195
180 IF R>=8.28 THEN 183
181 K3=2
182 GOTO 195
183 IF R>=13.28 THEN 190
184 K3=1
185 GOTO 195
190 K3=0
195 K9=K9+K3
200 B3=RND(0)
202 IF B3<=.97 THEN 206
204 B3=1
205 GOTO 221
206 B3=0
221 B9=B9+B3
230 S3=INT(RND(0)*8+1)
235 G(I,J)=K3*100+B3*10+S3
250 NEXT J
260 NEXT I
265 K0=K9
270 IF B9>0 THEN 285
271 I=INT(RND(0)*8+1)
272 J=INT(RND(0)*8+1)
275 G(I,J)=G(I,J)+10
276 B9=1
285 LET P2=1
294 PRINT
295 PRINT " POR FAVOR INGRESE PASSWORD SECRETO:";
296 INPUT X$
297 PRINT
298 LET N1=N9=N7=A7=0
300 REM: DETERMINAR COMANDANTE KLINGON
302 IF A9<>0 THEN 320
304 R1=INT(RND(0)*8+1)
306 R2=INT(RND(0)*8+1)
308 C2=R1
310 C3=R2
312 G(C2,C3)=G(C2,C3)+100
314 K9=K9+1
315 K0=K9
316 A9=A9+1
320 REM: CONTINUAR
399 GOTO 9045
400 REM: ESTABLECER CUADRANTE
405 K3=B3=S3=0
410 IF Q1<1 THEN 500
420 IF Q1>8 THEN 500
430 IF Q2<1 THEN 500
440 IF Q2>8 THEN 500
450 X=G(Q1,Q2)/99.999
460 K3=INT(X)
470 B3=INT((X-K3)*10.0)
480 S3=G(Q1,Q2)-INT(G(Q1,Q2)*.1)*10
490 'MAT K=ZER
491 FOR I=1 TO 8
492 FOR J=1 TO 8
493 Q(I,J)=0
494 NEXT J
495 NEXT I
500 FOR I=1 TO 8
510 FOR J=1 TO 8
520 Q(I,J)=0
530 NEXT J
540 NEXT I
545 IF N1<>1 THEN 550
548 Q(S1,S2)=5
549 GOTO 560
550 Q(S1,S2)=1
560 FOR I=1 TO K3
570 GOSUB 9000
580 Q(R1,R2)=2
590 K(I,1)=R1
591 K(I,2)=R2
593 K(I,3)=S9
600 NEXT I
601 IF Q1<>C2 THEN 610
602 IF Q2<>C3 THEN 610
603 K(I,3)=800
605 Q(K(I,1),K(I,2))=6
610 FOR I=1 TO B3
620 GOSUB 9000
630 Q(R1,R2)=3
640 NEXT I
650 FOR I=1 TO S3
660 GOSUB 9000
670 Q(R1,R2)=4
680 NEXT I
690 A=-1
691 IF P2=1 THEN 700
693 GOSUB 5000
694 IF E<=0 THEN 5200
699 GOTO 955
700 REM: ESCANER DE CORTO ALCANCE
702 P2=P2+1
705 LET T8=S1-1
706 LET U=S1+1
707 LET M=S2-1
708 LET N=S2+1
709 IF T8>=1 THEN 711
710 T8=1
711 IF U<=8 THEN 713
712 U=8
713 IF M>=1 THEN 715
714 M=1
715 IF N<=8 THEN 720
716 N=8
720 FOR I=T8 TO U
725 FOR J=M TO N
735 IF Q(I,J)<>3 THEN 740
736 C$="ACOPLADO"
737 GOSUB 7700
739 GOTO 801
740 NEXT J
745 NEXT I
770 IF K3>0 THEN 790
775 IF E<E0*.1 THEN 800
780 C$="VERDE"
785 GOTO 801
790 C$="ROJA"
795 GOTO 801
800 C$="AMARILLO"
801 IF A<0 THEN 803
802 GOTO 804
803 GOSUB 5000
804 IF E<=0 THEN 5200
805 IF D(2) >= 0 THEN 830
815 PRINT "SENSORES DE CORTO ALCANCE DESTRUIDOS "
820 PRINT
825 GOTO 955
830 PRINT "------------------------------------"
835 FOR I=1 TO 8
836 FOR J=1 TO 8
838 PRINT Q$(Q(I,J)+1);" ";
840 NEXT J
841 PRINT " ";
845 GOSUB 854
847 NEXT I
848 PRINT "--------------------------"
849 GOTO 955
854 IF I>1 THEN 859
855 PRINT "FECHA ESTELAR "T
856 GOTO 900
859 IF I>2 THEN 864
860 PRINT "CONDICION "C$
861 GOTO 900
864 IF I>3 THEN 869
865 PRINT "CUADRANTE "Q1;"-"Q2
866 GOTO 900
869 IF I>4 THEN 874
870 PRINT "SECTOR "S1;"-"S2
871 GOTO 900
874 IF I>5 THEN 879
875 PRINT "ENERGIA "E
876 GOTO 900
879 IF I>6 THEN 884
880 PRINT "TORPEDOS FOTON "P
881 GOTO 900
884 IF I>7 THEN 890
885 PRINT "KLINGON RESTANTES"K9
886 GOTO 900
890 PRINT "ESCUDO DE ENERGIA"Z$
900 RETURN
955 IF N9<>1 THEN 959
956 GOSUB 7950
957 IF N7=1 THEN 3582
958 N9=2
959 PRINT "COMANDO:";
960 INPUT A
961 IF C$<>"ACOPLADO" THEN 964
962 GOSUB 7700
964 GOTO 7100
974 PRINT
975 PRINT " 0 = PONER RUMBO"
980 PRINT " 1 = ESCANEO DE CORTO ALCANCE"
985 PRINT " 2 = ESCANEO DE LARGO ALCANCE"
990 PRINT " 3 = DISPARA PHASERS"
995 PRINT " 4 = DISPARA TORPEDOS DE FOTON"
1000 PRINT " 5 = REPORTE DE CONTROL DE AVERIAS"
1005 PRINT " 6 = AUTODESTRUCCION"
1006 PRINT " 7 = ABANDONAR NAVE"
1007 PRINT " 8 = ACTIVAR ESCUDOS DE ENERGIA"
1008 PRINT " 9 = DESACTIVAR ESCUDOS ENERGIA"
1009 PRINT " 10 = DISPARAR RAYO EXPERIMENTAL"
1018 IF H6=1 THEN 9946
1019 PRINT
1020 GOTO 955
1030 REM: WARP DRIVE
1035 C$="MOVIENDO"
1040 PRINT "CURSO (1-8.9999):";
1050 INPUT C1
1060 IF C1=0 THEN 955
1070 IF C1<1 THEN 959
1080 IF C1>= 9 THEN 1040
1090 PRINT "VELOCIDAD WARP (0-12):";
1100 INPUT W1
1110 IF W1<0 THEN 959
1120 IF W1>12 THEN 959
1130 IF W1<=.25 THEN 1163
1140 IF D(1) >= 0 THEN 1163
1150 PRINT "MOTORES WARP AVERIADOS, VELOCIDAD MAXIMA = WARP .25"
1160 GOTO 1040
1163 GOTO 7500
1164 E=E-C5
1165 IF E<=0 THEN 5200
1168 IF W1=12 THEN 3500
1170 REM: THIS IS A CONTINUE CARD
1180 GOSUB 5000
1185 IF N9=1 THEN 955
1190 IF E <=0 THEN 5230
1200 FOR I=1 TO 7
1215 IF D(I)=0 THEN 1230
1220 D(I)=D(I)+2
1222 IF D(I)<0 THEN 1230
1225 D(I)=0
1230 NEXT I
1240 IF RND(0)>.20 THEN 1320
1250 R1=INT(RND(0)*7+1)
1260 IF RND(0)>.5 THEN 1300
1270 D(R1)=D(R1)-(RND(0)*5+1)
1280 PRINT "*** TORMENTA ESPACIAL, ";
1281 GOSUB 6000
1283 PRINT F$" AVERIADO ***"
1290 GOTO 1320
1300 FOR I=R1 TO 7
1301 IF D(I)<0 THEN 1307
1302 NEXT I
1303 FOR I=1 TO R1-1
1304 IF D(I)<0 THEN 1307
1305 NEXT I
1306 GOTO 1320
1307 R1=I
1308 D(I)=D(I)+RND(0)*5+1
1309 IF D(I)<=0 THEN 1311
1310 D(I)=0
1311 PRINT "*** TEGUA TEMPORAL, ";
1312 GOSUB 6000
1313 PRINT F$" ESTADO DE REPARACION MEJORADO ***"
1320 N=INT(W1*8)
1322 E=E-N-N+5
1324 T=T+1
1326 Q(S1,S2)=0
1327 X=S1
1328 Y=S2
1330 IF T>T0+T9 THEN 5200
1340 GOSUB 3460
1350 FOR I=1 TO N
1352 S1=S1+X1
1354 S2=S2+X2
1356 X3=INT(S1+.5)
1357 Y3=INT(S2+.5)
1370 IF S1<.5 THEN 1480
1375 IF S2<.5 THEN 1480
1380 IF S1>=8.5 THEN 1480
1385 IF S2>=8.5 THEN 1480
1388 IF Q(X3,Y3)<>0 THEN 1392
1390 NEXT I
1391 GOTO 1460
1392 LET Z5=Q(X3,Y3)
1393 IF Z5=6 THEN 6300
1394 IF Z5<>2 THEN 1405
1400 GOTO 6300
1405 PRINT
1406 GOSUB 7900
1407 PRINT N$;"BLOQUEADO POR OBJETO EN SECTOR"S1;"-"S2
1408 S1=S1-X1
1410 S2=S2-X2
1460 S1=INT(S1+.5)
1465 S2=INT(S2+.5)
1467 Q(S1,S2)=A5
1470 GOTO 955
1480 Q1=INT(Q1+W1*X1+(X-.5)/8)
1481 Q2=INT(Q2+W1*X2+(Y-.5)/8)
1482 IF Q1>=1 THEN 1485
1483 Q1=1
1484 Z2=1
1485 IF Q1<=8 THEN 1488
1486 Q1=8
1487 Z2=1
1488 IF Q2>=1 THEN 1491
1489 Q2=1
1490 Z2=1
1491 IF Q2<=8 THEN 1494
1492 Q2=8
1493 Z2=1
1494 IF Z2<>1 THEN 1497
1496 GOSUB 8970
1497 PRINT
1498 IF G(Q1,Q2)>999 THEN 7650
1499 Z2=0
1500 S1=INT(RND(0)*8+1)
1510 S2=INT(RND(0)*8+1)
1550 GOTO 400
1600 REM: ESCANEO DE SENSOR DE LARGO ALCANCE
1610 IF D(3) >= 0 THEN 1640
1620 PRINT "SENSORES DE LARGO ALCANCE INOPERATIVOS"
1625 PRINT
1630 GOTO 955
1640 PRINT "ESCANEO DE LARGO ALCANCE PARA CUADRANTE"Q1","Q2
1645 PRINT "----------------- '"
1660 FOR I=Q1-1 TO Q1+1
1670 N(1)=N(2)=N(3)=0
1680 FOR J=Q2-1 TO Q2+1
1690 IF I<1 THEN 1740
1700 IF I>8 THEN 1740
1710 IF J<1 THEN 1740
1720 IF J>8 THEN 1740
1730 N(J-Q2+2)=G(I,J)
1740 NEXT J
1750 PRINT ":"N(1);":"N(2);":"N(3)
1760 PRINT "------------------- '"
1770 NEXT I
1775 PRINT
1780 GOTO 955
1800 REM: CONTROL DE PHASER
1810 IF D(4) >= 0 THEN 1832
1820 PRINT "CONTROL DE PHASER ESTA DESACTIVADO"
1825 PRINT
1830 GOTO 955
1832 IF C5=0 THEN 1840
1834 PRINT "DEBE BAJAR ESCUDOS PARA DISPARAR."
1836 PRINT
1837 GOTO 959
1840 PRINT "PHASERS APUNTADOS A OBJETIVO. ENERGIA DISPONIBLE = "E
1850 PRINT "CANTIDAD DE UNIDADES A DISPARAR:";
1860 INPUT X
1870 IF X <= 0 THEN 955
1880 IF E-X<0 THEN 1840
1890 E=E-X
1895 IF K3=0 THEN 2010
1898 W2=K3
1900 FOR I=1 TO 9
1910 IF K(I,3) <= 0 THEN 1990
1929 H=(X)/(FNO(I))*(3.0+RND(0))
1930 K(I,3)=K(I,3)-(H/W2)
1940 PRINT H/W2;"UNIDAD DIO AL KLINGON EN SECTOR"K(I,1);"-"K(I,2)
1950 PRINT "("K(I,3);"RESTANTES)"
1960 IF K(I,3)>0 THEN 1990
1970 GOSUB 4500
1980 IF K9 <= 0 THEN 5300
1990 NEXT I
1995 IF K3<=0 THEN 2020
2000 GOSUB 5000
2010 IF E <= 0 THEN 5250
2020 GOTO 955
3000 REM: TORPEDOS DE FOTON
3010 IF D(5) >= 0 THEN 3040
3020 PRINT "TUBOS DE FOTON INOPERATIVOS"
3025 PRINT
3030 GOTO 955
3040 IF P>0 THEN 3062
3050 PRINT "TODOS LOS TORPEDOS DE FOTON AGOTADOS"
3060 GOTO 955
3062 IF C5=0 THEN 3068
3064 PRINT "DEBE BAJAR ESCUDOS PARA DISPARAR."
3066 PRINT
3067 GOTO 959
3068 PRINT "DESEA DISPARAR EN ABANICO:";
3069 INPUT M$
3070 PRINT "CURSO DE TORPEDO (1-8.9999):";
3080 INPUT C1
3090 IF C1=0 THEN 955
3100 IF C1<1 THEN 3070
3110 IF C1>=9 THEN 3070
3111 IF P<3 THEN 3120
3116 IF M$="SI" THEN 6500
3120 GOSUB 3460
3130 X=S1
3132 Y=S2
3134 P=P-1
3140 PRINT "RASTRO TORPEDO:";
3150 X=X+X1
3155 Y=Y+X2
3160 IF X<.5 THEN 3422
3165 IF Y<.5 THEN 3422
3170 IF X>=8.5 THEN 3422
3175 IF Y>=8.5 THEN 3422
3200 PRINT X;"-"Y;
3202 X5=INT(X+.5)
3204 Y5=INT(Y+.5)
3210 IF Q(X5,Y5)<>0 THEN 3230
3220 GOTO 3150
3230 LET F7=Q(X5,Y5)
3236 IF F7=1 THEN 3150
3237 IF F7=2 THEN 3244
3238 IF F7=3 THEN 3301
3239 IF F7=4 THEN 3323
3240 IF F7=6 THEN 3244
3244 PRINT
3245 PRINT "*** KLINGON DESTRUIDO ***"
3250 K3=K3-1
3255 K9=K9-1
3260 IF K9<=0 THEN 5300
3271 FOR I=1 TO 9
3272 IF K(I,1)<>X5 THEN 3275
3273 IF K(I,2)<>Y5 THEN 3275
3274 GOTO 3400
3275 NEXT I
3301 Q(X5,Y5)=0
3310 PRINT
3311 PRINT "*** BASE ESTELAR DESTRIDA ... FELICITACIONES ***"
3313 B3=B3-1
3315 GOTO 3410
3323 Q(X5,Y5)=0
3334 PRINT
3335 PRINT "***ESTRELLA DESTRUIDA***"
3340 S3=S3-1
3345 IF S3>=0 THEN 3410
3347 S3=0
3350 GOTO 3410
3400 K(I,3)=0
3401 Q(X5,Y5)=0
3410 G(Q1,Q2)=K3*100+B3*10+S3
3420 GOTO 3430
3422 PRINT
3425 PRINT "TORPEDO ERRADO"
3430 IF E4=0 THEN 3439
3432 E4=E4+1
3433 IF E4>3.5 THEN 3438
3435 GOTO 6520
3438 IF K3<=0 THEN 3445
3439 GOSUB 5000
3440 IF E <= 0 THEN 5230
3445 E4=0
3450 GOTO 955
3460 X2=COS((C1-1)*.785398)
3470 X1=-SIN((C1-1)*.785398)
3480 RETURN
3500 W9=RND(0)
3502 IF T>T0+15 THEN 3510
3504 PRINT "NO PUEDE USARSE WARP 12 HASTA FECHA ESTELAR"T0+16
3506 GOTO 1040
3510 PRINT "VELOCIDAD APROXIMANDO WARP 12."
3520 PRINT "MOTORES OPERANDO ENCIMA DE NIVEL PELIGROSO."
3530 PRINT "TODOS LOS DISPOSITIVOS DE SEGURIDAD INOPERATIVOS."
3540 PRINT "SOBRECALENTAMIENTO CRITICO--EXPLOSION ESPONTANEA INMINENTE."
3570 IF W9>.40 THEN 3600
3575 FOR I=1 TO 2
3576 PRINT "***********************************************************"
3577 NEXT I
3578 GOSUB 7900
3580 PRINT "*** ENTROPIA DE"N$;"MAXIMIZADA **************"
3582 GOSUB 9980
3583 PRINT " YOU ATE THAT ONE."
3584 GOTO 9992
3600 IF W9>.55 THEN 3700
3610 PRINT
3620 PRINT " ESTA VIAJANDO AL PASADO."
3630 T=T-6
3640 PRINT "*** FECHA ESTELAR ="T+1
3650 GOTO 1170
3700 IF W9>.60 THEN 3800
3710 PRINT
3720 PRINT " ESTA VIAJANDO AL PASADO."
3730 T=T-11
3740 PRINT "*** FECHA ESTELAR ="T+1
3750 GOTO 1170
3800 IF W9>.70 THEN 3900
3810 PRINT
3820 PRINT " ESTA VIAJANDO AL FUTURO."
3830 T=T+5
3840 IF T>T0+T9 THEN 5200
3850 PRINT "*** FECHA ESTELAR ="T
3860 GOTO 1170
3900 PRINT
3910 PRINT "REACCION NUCLEAR EN CADENA DEL REACTOR DETENIDA."
3920 PRINT "*** PORTAL DE TIEMPO PERDIDO ***"
3930 GOTO 1170
4000 REM: REPORTE DE CONTROL DE AVERIAS
4010 IF D(6) >= 0 THEN 4040
4020 PRINT "REPORTE DE CONTROL DE AVERIAS NO DISPONIBLE"
4025 PRINT
4030 GOTO 955
4040 PRINT
4050 PRINT "DISPOSITIVO ESTADO DE REPARACION"
4060 FOR I=1 TO 7
4065 R5=I-.5
4066 GOSUB 6000
4070 PRINT F$,D(I)
4080 NEXT I
4090 PRINT
4100 GOTO 955
4200 REM:
4500 PRINT "*** KLINGON EN SECTOR"K(I,1);"-"K(I,2);"DESTRUIDO."
4510 K3=K3-1
4520 K9=K9-1
4530 Q(K(I,1),K(I,2))=0
4540 G(Q1,Q2)=K3*100+B3*10+S3
4550 RETURN
5000 REM: ATAQUE KLINGON
5002 GOSUB 7900
5003 IF K3<=0 THEN 5110
5005 IF C$ <> "ACOPLADO" THEN 5017
5010 PRINT "ESCUDOS DE BASE ESTELAR PROTEGEN EL"N$
5012 RETURN
5017 IF C5=0 THEN 5022
5018 PRINT "** ATAQUE KLINGON-- ESCUDOS DE ENERGIA PROTEGEN"N$
5020 GOTO 5110
5022 IF K3*150<E THEN 5049
5023 IF N1<>0 THEN 5049
5024 PRINT
5025 PRINT " COMANDANTE KLINGON AL ENTERPRISE---"
5026 PRINT "COMO BIEN SABE, ESTA PELIGROSAMENTE ESCASO DE ENERGIA"
5027 PRINT "Y PROBABLEMENTE SERA DESTRUIDO EN MI SIGUIENTE ATAQUE."
5028 PRINT "COMO OFICIAL Y CABALLERO, LE OFREZCO LA OPORTUNIDAD DE"
5029 PRINT "SALVARSE USTED Y SU TRIPULACION----"
5032 PRINT " SE RINDE?:";
5033 INPUT S$
5034 IF S$<>"SI" THEN 5049
5035 A7=1
5036 N9=1
5038 GOTO 5110
5049 PRINT
5050 FOR I=1 TO 9
5051 IF K(I,3) <= 0 THEN 5100
5060 H=(K(I,3)/FNO(I))*(2+RND(0))
5070 E=E-H
5075 GOSUB 7900
5080 PRINT H;"UNIDAD IMPACTADA EN"N$;"POR KLINGON, SECTOR "K(I,1);"-"K(I,2)
5082 IF H<=180 THEN 5090
5083 R5=INT(RND(0)*7+1)
5084 D(R5)=D(R5)-(RND(0)*5+1)
5085 PRINT "*** IMPACTO CRITICO,";
5086 GOSUB 6000
5087 PRINT F$" AVEREIADO ***"
5090 PRINT "("E;"RESTANTE)"
5100 NEXT I
5105 PRINT
5110 RETURN
5200 REM: PERDER
5210 GOSUB 9985
5220 PRINT "ES FECHA ESTELAR"T
5230 PRINT
5250 GOSUB 7900
5255 PRINT "EL"N$;"HA SIDO DESTRUIDO."
5260 PRINT "RESTAN AUN"K9;"CRUCEROS DE BATALLA KLINGON."
5270 PRINT "LA FEDERACION SERA CONQUISTADA."
5280 PRINT "USTED HA MUERTO, TONTO INCOMPETENTE."
5290 GOTO 9992
5300 REM: WIN
5310 GOSUB 9985
5320 PRINT "ES LA FECHA ESTELAR"T
5330 PRINT "EL ULTIMO CRUCERO DE BATALLA KLINGON EN LA GALAXIA HA SIDO"
5331 PRINT "DESTRUIDO."
5340 PRINT "LA FEDERACION HA SIDO SALVADA."
5350 PRINT "USTED HA SIDO PROMOVIDO A COMODORO EMERITO."
5355 IF N1<>0 THEN 5380
5360 PRINT K0;"KLINGONS EN"T-T0;"ANIOS. RATING="INT(K0/(T-T0)*1000)
5370 GOTO 9992
5380 PRINT K0;"KLINGONS EN"T-T0;"ANIOS."
5382 IF A7=5 THEN 5392
5385 PRINT "ENTERPRISE CAPTURADO."
5390 PRINT "RATING ="INT(K0/(T-T0)*1000-1000)
5391 GOTO 9992
5392 PRINT "ENTERPRISE DESTRUIDO INTENCIONALMENTE."
5393 PRINT "RATING ="INT(K0/(T-T0)*1000-500)
5395 GOTO 9992
6000 REM: SELECCIONE DISPOSITIVO AVERIADO
6002 IF A+1<>1 THEN 6010
6004 R5=R1
6010 IF R5>1 THEN 6040
6020 F$="MOTORES WARP"
6030 GOTO 8000
6040 IF R5>2 THEN 6070
6050 F$="SENSORES C.A."
6060 GOTO 8000
6070 IF R5>3 THEN 6090
6075 F$="SENSORES L.A."
6080 GOTO 8000
6090 IF R5>4 THEN 6100
6093 F$="CNTRL PHASER"
6097 GOTO 8000
6100 IF R5>5 THEN 6110
6103 F$="TUBOS FOTON"
6107 GOTO 8000
6110 IF R5>6 THEN 6115
6111 F$="CNTRL AVERIA"
6112 GOTO 8000
6115 F$="ESCD ENERGIA"
6118 GOTO 8000
6300 REM: EMBESTIR A KLINGON
6301 PRINT
6302 Q(S1,S2)=0
6304 K3=K3-1
6305 K9=K9-1
6310 Z$="ABAJO"
6318 FOR I=1 TO 9
6320 IF K(I,1)<>X3 THEN 6330
6322 IF K(I,2)<>Y3 THEN 6330
6323 Z6=K(I,1)
6324 Z7=K(I,2)
6325 GOTO 6360
6330 NEXT I
6360 K(I,3)=0
6362 GOSUB 7900
6363 Q(X3,Y3)=A5
6365 GOTO 6370
6370 G(Q1,Q2)=K3*100+B3*10+S3
6380 PRINT "*** ALERTA DE EMERGENCIA ***"
6381 PRINT "*** COLISION IMMINENTE ***"
6382 GOSUB 9980
6383 GOSUB 7900
6384 PRINT N$;"EMBISTE KLINGON EN SECTOR"Z6;"-"Z7
6385 PRINT "*** KLINGON DESTRUIDO,"N$;"GRAVEMENTE AVERIADO. ***"
6386 FOR I=1 TO 7
6387 D(I)=D(I)-(RND(0)*4+1)
6388 NEXT I
6389 C5=0
6390 E=E-500
6391 IF K9<=0 THEN 5300
6395 IF E<=0 THEN 5230
6396 S1=Z6
6397 S2=Z7
6398 A=2
6399 GOTO 4040
6500 REM: FORMACION DE ABANICO DE TORPEDO
6507 PRINT "ANGULO DE APERTURA (0.05-0.30):";
6508 INPUT E5
6509 IF E5=0 THEN 959
6510 IF E5<0.05 THEN 6507
6511 IF E5>0.30 THEN 6507
6515 E4=1
6520 PRINT "CANTIDAD"E4;
6522 IF E4>1.5 THEN 6530
6524 C1=C1-E5
6525 GOTO 3120
6530 C1=C1+E5
6535 GOTO 3120
7100 REM: ENLACE DE MANDO
7105 IF A+1 = 1 THEN 1030
7106 IF A+1 = 2 THEN 700
7107 IF A+1 = 3 THEN 1600
7108 IF A+1 = 4 THEN 1800
7109 IF A+1 = 5 THEN 3000
7110 IF A+1 = 6 THEN 4000
7111 IF A+1 = 7 THEN 8100
7112 IF A+1 = 8 THEN 7400
7113 IF A+1 = 9 THEN 7800
7114 IF A+1 = 10 THEN 7850
7115 IF A+1 = 11 THEN 7200
7125 GOTO 974
7200 REM: RAYO DE LA MUERTE
7202 IF T>T0+18 THEN 7208
7204 PRINT " EL RAYO DE LA MUERTE NO PUEDE USARSE HASTA FECHA ESTELAR"T0+19
7205 PRINT
7206 GOTO 959
7208 IF W3<.05 THEN 7215
7210 PRINT " RAYO DE LA MUERTE PERMANENTEMENTE FUERA DE SERVICIO."
7212 PRINT
7214 GOTO 959
7215 IF C5=0 THEN 7225
7220 PRINT " DEBE BAJAR ESCUDOS PARA DISPARAR."
7222 PRINT
7223 GOTO 959
7225 W3=RND(0)
7227 PRINT
7228 IF W3>.35 THEN 7260
7230 PRINT " *SOBRECARGA DE ANTIMANTERIA."
7231 PRINT " PSEUDOESTRELLAS CREADAS TEMPORALMENTE A PARTIR DE ENERGIA."
7232 FOR I=1 TO 8
7233 FOR J=1 TO 8
7235 IF Q(I,J)<>0 THEN 7240
7238 Q(I,J)=4
7240 NEXT J
7241 NEXT I
7245 PRINT
7247 GOTO 830
7260 IF W3>.50 THEN 7280
7263 PRINT "*** RAYO DE LA MUERTE FALLA CATASTROFICA ***"
7265 PRINT "*** MEJOR SUERTE LA PROXIMA VEZ ***"
7270 GOTO 3575
7280 IF W3>.60 THEN 7310
7283 PRINT "*** RAYO DE LA MUERTE ANIQUILA TODOS LOS KLINGONS EN CUADRANTE"Q1;"-"Q2
7285 K9=K9-K3
7286 IF K9<=0 THEN 5300
7287 FOR I=1 TO 8
7288 FOR J=1 TO 8
7289 IF Q(I,J)<>6 THEN 7292
7290 Q(I,J)=0
7292 IF Q(I,J)<>2 THEN 7294
7293 Q(I,J)=0
7294 NEXT J
7295 NEXT I
7296 K3=0
7298 G(Q1,Q2)=INT(B3*10+S3)
7300 GOTO 959
7310 IF W3>.75 THEN 7325
7312 PRINT "*VACIADO DE ENERGIA DEL REACTOR TERMAL."
7314 E=E-(.95*E)
7316 PRINT .95*E"UNIDADES DE ENERGIA QUEMADAS."
7320 GOTO 7283
7325 IF W3>.95 THEN 7350
7328 PRINT "*TRANSFORMACION MATERIA/ANTIMATERIA."
7330 IF K3>0 THEN 7334
7332 GOTO 7231
7334 PRINT "KLINGONS ALCANZADOS POR RAYO PRINCIPAL DUPLIOCADO."
7335 P8=K3
7338 FOR I=1 TO P8
7339 IF K3>8 THEN 7345
7341 K3=K3+1
7342 K9=K9+1
7344 NEXT I
7345 G(Q1,Q2)=K3*100+B3*10+S3
7346 P2=1
7349 GOTO 1500
7350 PRINT "*** RAYO DE LA MUERTE DESCONTROLADO ***"
7352 PRINT "*** DESTRUYE TODO KLINGON EN LA GALAXIA ***"
7353 PRINT "*** TAMBIEN DESTRUYE AL ENTERPRISE ***"
7354 A7=N1=5
7360 GOTO 5300
7400 REM: ABANDONAR NAVE
7401 IF N1=0 THEN 7404
7402 PRINT "LA FAIRIE QUEENE NO PUEDE SER ABANDONADA."
7403 GOTO 959
7404 PRINT
7405 IF A7<>1 THEN 7420
7410 PRINT "** NO PUEDE ABANDONAR LA NAVE TRAS HABERLE SIDO "
7411 PRINT "PEDIDO LA RENDICION."
7415 PRINT
7416 GOTO 959
7420 PRINT "*** ABANDONAR NAVE ***"
7421 PRINT "*** ABANDONAR NAVE ***"
7425 PRINT
7426 PRINT "SERIE ENTER-BLITZ INICIADA."
7429 PRINT "AUTORIZACION A PRUEBA DE FALLOS INSERTADO."
7433 PRINT "COMANDANTE DEL ENTERPRISE Y TRIPULACION ESCAPAN EN TRANSBORDADOR."
7435 PRINT
7440 PRINT "*** ENTERPRISE REDUCIDO A PARTICULAS SUBATOMICAS ***"
7441 PRINT
7445 A7=5
7446 N1=1
7448 N9=1
7450 GOTO 955
7500 REM: SUPERNOVA
7501 IF V=2 THEN 7506
7502 IF RND(0)>.15 THEN 7600
7504 GOTO 7508
7506 IF RND(0)>.10 THEN 7600
7508 Z3=INT(RND(0)*8+1)
7510 Z4=INT(RND(0)*8+1)
7515 IF G(Z3,Z4)>999 THEN 7600
7520 S4=G(Z3,Z4)-INT(G(Z3,Z4)*.1)*10
7525 IF S4<=0 THEN 7600
7530 PRINT
7535 PRINT "********************************************************"
7540 PRINT "********* SUPERNOVA EN CUADRANTE"Z3;"-"Z4
7542 PRINT "TODA LA MATERIA EN ESTE CUADRANTE CONVERTIDA EN ENERGIA."
7543 IF Q1<>Z3 THEN 7575
7544 IF Q2<>Z4 THEN 7575
7545 PRINT
7546 GOSUB 7900
7548 PRINT "DESAFORTUNADAMENTE, EL"N$;"ESTABA EN ESTE CUADRANTE."
7550 GOTO 3582
7575 PRINT "DE AHORA EN MAS, CUALQUIER NAVE DETENIDA EN ESTE CUADRANTE"
7576 PRINT "SERA TOTALMENTE ENERGIZADA."
7577 PRINT "********************************************************"
7579 PRINT
7580 K4=INT(G(Z3,Z4)/99.99)
7582 B4=INT((G(Z3,Z4)/99.99-K4)*10.0)
7584 B9=B9-B4
7585 K9=K9-K4
7590 G(Z3,Z4)=INT(1000.0)
7600 GOTO 1164
7650 REM: NAVE ENCUENTRA ANTIGUA SUPERNOVA
7655 PRINT "*** EY ESTUPIDO. LE FUE ADVERTIDO NO DETENERSE EN UN"
7656 PRINT "CUADRANTE DONDE OCURRIO UNA SUPERNOVA."
7660 GOTO 8992
7700 REM: VARIABLE RESUPPLY
7701 IF N1=1 THEN 7710
7703 E=3000
7705 P=10
7708 GOTO 7720
7710 E=1500
7715 P=5
7720 A7=0
7730 RETURN
7800 REM: ACTIVATE ENERGY SHIELDS
7802 IF D(7)>=0 THEN 7808
7804 PRINT "ESCUDOS DE ENERGIA DESACTIVADOS."
7806 GOTO 959
7808 IF C5=0 THEN 7818
7810 PRINT "ESCUDOS DE ENERGIA YA ACTIVADOS."
7811 PRINT
7812 GOTO 959
7818 PRINT
7819 PRINT "ESCUDOS DE ENERGIA ACTIVADOS."
7820 PRINT
7822 C5=200
7824 Z$="ARRIBA"
7825 E=E-C5
7826 IF E<=0 THEN 5200
7828 GOSUB 5000
7830 GOTO 959
7850 REM: DEACTIVATE ENERGY SHIELDS
7855 PRINT
7860 PRINT "ESCUDOS DE ENERGIA DESACTIVADOS."
7863 PRINT
7865 C5=0
7868 Z$="ABAJO"
7870 GOSUB 5000
7875 GOTO 955
7900 REM: DETERMINE NAME
7905 IF N1<>1 THEN 7915
7908 A5=5
7910 N$=" FAIRIE QUEENE "
7912 GOTO 7920
7915 N$=" ENTERPRISE "
7918 A5=1
7920 RETURN
7950 REM: CAMBIANDO LA GUARDA EN EL PALACIO DE BUCKINGHAM
7951 PRINT
7952 FOR I=1 TO 8
7955 FOR J=1 TO 8
7957 K3=INT(G(I,J)/99.99)
7958 B3=INT((G(I,J)/99.99-K3)*10.0)
7960 IF B3>0 THEN 7978
7961 NEXT J
7962 NEXT I
7963 PRINT " HA SIDO LLEVADO AL CUARTEL GENERAL KLINGON."
7964 PRINT "SI TUVIESE UNA BASE ESTELAR, SERIA REPATRIADO"
7965 PRINT "Y DADO UNA NUEVA NAVE A COMANDAR."
7966 PRINT "COMO NO TIENE UNA BASE ESTELAR, SERA INMISERICORDEMENTE"
7967 PRINT "TORTURADO HASTA MORIR POR SU ACHIAMIGO,"
7968 PRINT "CECIL DYBOWSKI, ESCORIA DEL UNIVERSO."
7970 N7=1
7975 GOTO 8000
7978 N9=2
7979 T=T+1
7980 Q1=I
7981 Q2=J
7982 E=1500
7983 P=5
7984 N1=1
7985 PRINT "HA SIDO ENVIADO AL COMANDO DE LA FLOTA ESTELAR."
7987 PRINT "TIENE EL MANDO DE UNA NUEVA NAVE ESTELAR,"
7988 PRINT " EL FAIRIE QUEENE,"
7989 PRINT "qUE APARECE COMO /Q/ EN LOS SENSORES."
7990 PRINT
7992 PRINT " EL FAIRIE QUEENE SE ENCUENTRA ACTUALMENTE EN EL CUADRANTE"Q1;"-"Q2
7994 PRINT "INTENTE SER MAS CUIDADOSO ESTA VEZ."
7995 FOR I=1 TO 7
7996 D(I)=0
7997 NEXT I
7998 PRINT
7999 GOTO 1500
8000 RETURN
8050 Q$(1)="."
8051 Q$(2)="E"
8052 Q$(3)="K"
8053 Q$(4)="B"
8054 Q$(5)="*"
8055 Q$(6)="Q"
8056 Q$(7)="C"
8060 RETURN
8100 REM: AUTODESTRUCCION
8105 PRINT
8110 PRINT "SERIES ENTER-BLITZ INICIALIZADA."
8115 PRINT "ESTA NAVE SE AUTODESTRUIRA EN DIEZ SEGUNDOS."
8116 PRINT "10"
8117 PRINT " 9"
8118 PRINT " 8"
8119 PRINT " 7"
8120 PRINT " 6"
8122 PRINT
8123 PRINT "T MENOS 5 SEGUNDOS Y CONTANDO."
8124 PRINT "MECANISMO DE SEGURIDAD ACTIVADO. SOLO EL COMANDANTE DE"
8125 PRINT "LA NAVE ESTELAR PUEDE ANULAR ESTO CON SU PASSWORD SECRETO."
8126 PRINT "EL OFICIAL DE CIENCIA HICKS YA HA INGRESADO SU CONTRA"
8127 PRINT "PASSWORD CORRECTO."
8128 PRINT "PARA CONTINUAR LA SERIE ENTER-BLITZ, INGRESE SU "
8129 PRINT "PASSWORD SECRETA:";
8130 INPUT V$
8135 IF V$<>X$ THEN 8150
8139 PRINT
8140 PRINT " 4"
8141 PRINT " 3"
8142 PRINT " 2"
8143 PRINT " 1"
8145 GOTO 3575
8150 PRINT
8151 PRINT "SERIE ENTER-BLITZ TERMINADA."
8155 PRINT
8160 GOTO 955
8200 REM: RANDOMIZE
8205 PRINT
8206 PRINT " INGRESE UN NUMERO RARO ENTRE 0.0 Y 1.0 :";
8207 INPUT E6
8208 E9=RND(E6)
8210 RETURN
8970 REM: ABANDONAR GALAXIA
8975 IF F>2 THEN 8990
8980 PRINT
8981 PRINT "STARSHIP ENCOUNTERS END OF GALAXY."
8982 PRINT
8983 PRINT "TONTO MORTAL, HAS INTENTADO AVENTURARTE FUERA DE LA"
8984 PRINT "GALAXIA Y AL SUBESPACIO. LA TERCERA VEZ QUE LO INTENTES,"
8985 PRINT "EL DIOS VIVIENTE, KORP, TE DESTRUIRA."
8987 F=F+1
8988 GOTO 8995
8990 PRINT
8991 PRINT "TE HAS ATREVIDO A ENTRAR AL SUBESPACIO POR TERCERA VEZ."
8992 PRINT "POR ESTO, ************ HAS MUERTO ****************"
8993 GOTO 3575
8995 RETURN
9000 REM: GENERADOR DE NUMEROS ALEATORIOS
9010 R1=INT(RND(0)*8+1)
9020 R2=INT(RND(0)*8+1)
9030 IF Q(R1,R2) <> 0 THEN 9010
9040 RETURN
9045 PRINT
9050 PRINT "ORDENES: FECHA ESTELAR = "T
9060 PRINT
9070 PRINT " COMO COMANDANTE DE LA NAVE ESTELAR ENTERPRISE,"
9080 PRINT "SU MISION ES LIBERAR LA GALAXIA DE LA MORTAL AMENAZA"
9090 PRINT "KLINGON. PARA HACERLO, DEBES DESTRUIR LA "
9100 PRINT "FUERZA DE INVASION KLINGON DE "K9"CRUCEROS DE BATALLA."
9110 PRINT "TIENE"T9;"A~OS SOLARES PARA COMPLETAR SU MISION."
9120 PRINT "(EJ. HASTA FECHA ESTELAR"T0+T9;")."
9125 PRINT
9130 IF B9 > 1 THEN 9133
9131 PRINT " TENDRA UNA BASE ESTELAR DE APOYO."
9132 GOTO 9140
9133 PRINT " USTED TENDRA"B9"BASES ESTELARES DE APOYO."
9140 PRINT "CUANDO EL ENTERPRISE SE ACOPLA A UNA (ESTA POSICIONADA"
9150 PRINT "JUNTO A UNA) ES REABASTECIDA CON ENERGIA Y TORPEDOS"
9160 PRINT "DE FOTONES."
9161 PRINT "EL ENTERPRISE ACTUALMENTE ESTA EN EL"
9162 PRINT "CUADRANTE"Q1"-"Q2"SECTOR"S1"-"S2
9163 PRINT "NECESITA MAS INSTRUCCIONES (REVISADO 18 ABRIL 73)";
9164 INPUT A$
9166 PRINT
9170 IF A$<>"SI" THEN 400
9175 GOSUB 9980
9180 PRINT " LA GALAXIA SE DIVIDE EN 64 CUADRANTES CON"
9190 PRINT "LAS SIGUIENTES COORDINADAS:"
9200 PRINT " Y-- 1 2 3 4 5 6 7 8 '"
9210 PRINT " --------------------------------- X"
9220 FOR I=1 TO 8
9230 PRINT " ' : : : : : : : : : "I
9240 PRINT " --------------------------------- '"
9250 NEXT I
9260 PRINT
9270 PRINT
9280 PRINT
9300 PRINT "CADA CUADRANTE ESTA IGUALMENTE DIVIDIDO EN 64 SECTORES."
9310 GOSUB 9980
9320 PRINT "::: DISPOSITIVOS :::"
9330 PRINT
9340 PRINT "MOTORES WARP: "
9350 PRINT
9360 PRINT "CURSO = UN NUMERO REAL DE 1 A 8.99999."
9370 PRINT "LOS NUMEROS INDICAN LA DIRECCION COMENZANDO DE LA DERECHA"
9380 PRINT "Y ANTIHORARIO:"
9390 PRINT
9400 PRINT " 3"
9410 PRINT " 4 2"
9420 PRINT " /"
9430 PRINT " 5---*---1"
9440 PRINT " /"
9450 PRINT " 6 8"
9460 PRINT " 7"
9470 PRINT
9480 PRINT "VELOCIDAD WARP = UN NUMERO REAL DE 0 A 12."
9490 PRINT "DISTANCIA ATRAVESADA = ENTERO (VELOCIDAD WARP ) CUADRANTES:"
9500 PRINT " WARP .2 = EL ENTERPRISE VIAJA 1 SECTOR."
9510 PRINT " .5 = 4 SECTORES."
9520 PRINT " 1 = 1 CUADRANTE."
9530 PRINT " 2 = 2 CUADRANTES."
9535 PRINT
9540 PRINT
9550 PRINT "POR EJEMPLO, SI VIAJA DESDE:"
9560 PRINT "CUADRANTE 1 - 1, SECTOR 1 - 1, EN DIRECTION 1 A WARP 2"
9570 PRINT "SE DETENDRIA EN"
9580 PRINT "CUADRANTE 1 - 3, SECTOR 1 - 1 EN LA FECHA ESTELAR SIGUIENTE."
9590 PRINT
9591 PRINT " CUANDO CAMBIA CUADRANTES, NO OBSTANTE, LA POSICION DE"
9592 PRINT "TODOS LOS OBJETOS EN EL NUEVO CUADRANTE (INCLUYENDO AL ENTERPRISE)"
9593 PRINT "SE CAMBIAN AL AZAR PARA SIMULAR VIAJE 3-D."
9599 PRINT
9600 PRINT "*** NOTA: TODO USO DE MOTORES WARP REQUIERE UNA FECHA"
9610 PRINT "ESTELAR. SI EL ENTERPRISE RESULTA BLOQUEADO POR ALGO"
9620 PRINT "DURANTE EL VIAJE INTRACUADRANTE SE DETENDRÁ ANTE ELLO"
9630 PRINT "(Y PERDERA UNA FECHA ESTELAR) ***"
9631 PRINT
9632 PRINT "***NOTA: HAY UN PORTAL DE TIEMPO DISPONIBLE AL VIAJAR"
9633 PRINT "A WARP 12. PUEDE AVANZAR O RETROCEDER EN EL TIEMPO"
9634 PRINT "PERO TAMBIÉN TIENE UNA POSIBILIDAD DE 40%"
9635 PRINT "DE SER DESTRUIDO EN UNA IMPLOSION NUCLEAR."
9636 PRINT "UN FACTOR WARP DE 12 SOLO PUEDE USARSE TRAS 15 A~OS SOLARES."
9637 PRINT
9638 PRINT "***NOTA: SU EL ENTERPRISE CHOCA UNA NAVE KLINGON, YA SEA"
9639 PRINT "DELIBERADA O ACCIDENTALMENTE, EL KLINGON SERA"
9640 PRINT "DESTRUIDO Y EL ENTERPRISE GRAVEMENTE AVERIADO."
9649 GOSUB 9980
9650 PRINT "SENSORES DE CORTO ALCANCE:"
9660 PRINT
9670 PRINT " LOS SENSORES DE CORTO ALCANCE DEL ENTERPRISE DAN"
9680 PRINT "UNA IMAGEN DETALLADA DEL CUADRANTE EN EL QUE SE ENCUENTRA."
9690 PRINT "EN LA PANTALLA EL ENTERPRISE APARECE COMO /E/."
9700 PRINT "LOS CRUCEROS DE BATALLA KLINGON APARECEN COMO /K/."
9710 PRINT "LAS BASES ESTELARES APARECEN COMO /B/ Y LAS ESTRELLAS"
9715 PRINT "COMO * . LOS KLINGONS PUEDEN TENER UNA NAVE DE"
9715 PRINT "COMANDO PODEROSA, /C/."
9720 PRINT
9723 PRINT "***NOTA: ACOPLAR ES UN PROCEDIMIENTO DE DOS PASOS."
9724 PRINT "PRIMERO MUEVASE ADJACENTE A LA BASE. LUEGO HAGA UN"
9725 PRINT "ESCANEO DE CORTO ALCANCE."
9726 PRINT "MIENTRAS ESTA ACOPLADO, LOS ESCUDOS DE LA BASE ESTELAR"
9727 PRINT "PROTEGEN AL ENTERPRISE".
9729 PRINT
9730 PRINT "***NOTA: CONDICION AMARILLA SIGNIFICA QUE ESTA"
9731 PRINT "PELIGROSAMENTE BAJO DE ENERGIA Y DEBE IR RAPIDO A UNA BASE."
9735 GOSUB 9980
9736 PRINT "RAYO EXPERIMENTAL DE LA MUERTE"
9737 PRINT
9738 PRINT " EL RAYO DE LA MUERTE EXPERIMENTAL, COMO SU NOMBRE INDICA,"
9739 PRINT "ES IMPREDECIBLE. SIN EMBARGO, PUEDE PREDECIR CON CIERTO"
9740 PRINT "FAVOR, DADO LA SITUACION, HARA LO QUE QUE PUEDA CON ELLO"
9741 PRINT "EXISTEN POSIBILIADES DE QUE DESTRUYA MUCHOS KLINGONS. EXISTE"
9742 PRINT "UNA POSIBILIDAD DE DESTRIUIR MUCHOS KLINGONS, PERO PUEDEN"
9743 PRINT "SUCEDER EFECTOS SEGUNDARIOS INDESEADOS. PODRA PROBABLEMENTE"
9744 PRINT "DISPARARLO UNA VES, PERO NUNCA SE SABE. NO PUEDE USARSE"
9745 PRINT "HASTA QUE TRANSCURRAN 18 A~OS SOLARES."
9757 GOSUB 9980
9758 PRINT "SENSORES DE LARGO ALCANCE:"
9759 PRINT
9760 PRINT " LOS SENSORES DE LARGO ALCANCE DEL ENTERPRISE MUESTRAN"
9770 PRINT "LA CANTIDAD DE OBJETOS EN LOS EN LOS 9 CUADRANTES MAS CERCANOS,"
9771 PRINT "CON EL ENTERPRISE EL EL CENTRAL."
9780 PRINT "CADA DIGITO DEL NUMERO EN CADA CUADRO SIGNIFICA ALGO:"
9790 PRINT " THE ONES DIGIT REPRESENTS THE NUMBER OF STARS."
9800 PRINT " TENS STARBASES."
9810 PRINT " HUNDREDS KLINGONS."
9812 PRINT " THOUSANDS SUPERNOVA."
9820 PRINT "FOR EXAMPLE:"
9830 PRINT "319 SIGNIFICA 3 KLINGONS, 1 BASE ESTELAR, Y 9 ESTRELLAS."
9840 PRINT "206 SIGNIFICA 2 KLINGONS, 0 BASES, Y 6 ESTRELLAS."
9850 PRINT "7 SIGNIFICA 0 KLINGONS, 0 BASES ESTELARES, Y 7 ESTRELLAS."
9860 GOSUB 9980
9861 PRINT "ESCUDOS DE ENERGIA:"
9862 PRINT
9863 PRINT " MIENTRAS QUE LOS ESCUDOS DE ENERGIA D EUNA NAVE ESTAN ACTIVOS,"
9864 PRINT "LOS ATAQUES KLINGON SON LIMITADOS. CADA VEZ QUE SE MUEVE CON"
9865 PRINT "SUS ESCUDOS ARRIBA, SE USAN 200 UNIDADES DE ENERGÍA."
9866 PRINT "TAMBIEN, ACTIVAR ESCUDOS REQUIERE 200 UNIDADES."
9867 PRINT "NOTA: DEBE BAJAR SUS ESCUDOS PARA ATACAR."
9869 GOSUB 9980
9870 PRINT "PHASERS:"
9880 PRINT
9890 PRINT " UNA PORCION DE LA ENERGIA DISPONIBLE PUEDE DISPARARSE."
9900 PRINT "lA COMPUTADORA DE TIRO DIVIDE ESTA CANTIDAD ENTRE LOS"
9901 PRINT "CRUCEROS KLINGON EN EL CUADRANTE Y DETERMINA"
9902 PRINT "LAS VARIAS DIRECCIONES DE TIRO. LA EFECTIVIDAD"
9903 PRINT "DE UN TIRO DEPENDE PRINCIPALMENTE DE LA DISTANCIA AL"
9904 PRINT "OBJETIVO. UN CRUCERO DE BATALLA KLINGON COMIENZA CON"S9
9905 PRINT "UNIDADES DE ENERGIA. PUEDE DISPARAR UNA CANTIDAD IGUAL A"
9906 PRINT "TANTA ENERGIA COMO LE QUEDE RESTANTE."
9907 PRINT
9908 PRINT
9909 PRINT "TORPEDOS DE FOTON:"
9910 PRINT
9911 PRINT " INICIALMENTE EL ENTERPRISE TIENE"P0"TORPEDOS DE FOTON."
9912 PRINT "UN TORPEDO DESTRUYE TODO LO QUE TOCA. EL ALCANCE DE LOS"
9913 PRINT "TORPEDOS DE FOTON (COMO LOS PHASERS) SE LIMITAN A"
9914 PRINT "EL CUADRANTE ACTUAL. EL CURSO DE UN TORPEDO DE FOTON"
9915 PRINT "ES EL MISMO QUE EL DEL ENTERPRISE."
9916 PRINT "SI LO DESEA, PUEDE DISPARAR EN ABANICO HASTA TRES TORPEDOS"
9917 PRINT "A LA VEZ. HAY UN RETRASO DE TIEMPO AL LANZAR, AQUEL"
9918 PRINT "CON EL MENOR CURSO NUMÉRICO SE DISPARA PRIMERO."
9919 PRINT "POR EJEMPLO, UN CURSO DE TORPEDO DE 3.49 CON UNA APERTURA"
9920 PRINT "ANGULAR DE 0.24 DISPARARIA TORPEDOS EN LAS DIRECCIONES"
9921 PRINT "3.25, 3.49, Y 3.73 ."
9924 GOSUB 9980
9925 PRINT "REPORTE DE CONTROL DE AVERIAS:"
9926 PRINT " EL REPORTE DE CONTROL DE AVERIAS LISTA LOS DISPOSITOS"
9927 PRINT "PRINCIPALES Y EL ESTADO DE SU REPARACION. UN ESTADO NEGATIVO"
9928 PRINT "DE REPARACION INDICA UN DISPOSITIVO DESACTIVADO. LOS DISPOSITIVO"
9929 PRINT "PUEDEN AVERIARSE O REPARARSE POR UNA TORMENTA ESPACIAL O TREGUA"
9930 PRINT "TAMBIEN LOS DIPOSITIVOS DAÑADOS SE REPARARN EN 2 UNIDADES CADA"
9931 PRINT "FECHA ESTELAR"
9935 GOSUB 9980
9940 PRINT "COMANDOS:"
9941 PRINT
9942 H6=1
9944 GOTO 975
9946 H6=H6+1
9952 GOSUB 9980
9953 PRINT "P.D.--GUARDE ESTA COPIA DE LAS INSTRUCCIONES, PARA QUE"
9954 PRINT "LA PROXIMA NO NECESITE INSTRUCCIONES ADICIONALES Y PUEDA"
9955 PRINT "PROCEDER INMEDIATAMENTE A JUGAR."
9956 PRINT
9957 PRINT
9960 GOSUB 9980
9961 PRINT "CUANDO ESTE LISTO PARA CONTINUAR, TIPEE 9:";
9962 INPUT X
9963 GOSUB 9980
9965 GOTO 400
9980 REM
9985 FOR I=1 TO 3
9986 PRINT
9990 NEXT I
9991 RETURN
9992 PRINT
9993 PRINT
9994 PRINT " DESEA JUGAR NUEVAMENTE:";
9995 INPUT A$
9996 IF A$ ="SI" THEN 5
9997 PRINT
9998 PRINT " ** AVE ATQUE VALE **"
9999 END
