10 REM POLINOMIO.BAS
20 REM RESUELVE ECUACIONES
30 REM POLINOMICAS Y DIFERENCIALES
40 KEY OFF : COLOR 3 'CYAN
50 I=0 : MX=20
60 DIM A(MX),D(MX)
70 OP1$="1 - POLINOMICA"
80 OP2$="2 - DIFERENCIAL"
90 OP3$="3 - SALIR DEL PROGRAMA"
100 CLS
110 PRINT OP1$
120 PRINT OP2$
130 PRINT OP3$
140 PRINT : PRINT
150 PRINT "PRESIONE NUMERO DE LA OPCION: ";
160 CHOICE=VAL(INPUT$(1))
170 IF CHOICE<1 OR CHOICE>3 GOTO 160
180 ON CHOICE GOSUB 280,530,200
190 GOTO 100
200 COLOR 7,0
210 CLS
220 FOR I=1 TO 10
230   PRINT
240 NEXT I
250 PRINT TAB(20);"PROGRAMA FINALIZADO, GRACIAS"
260 END
270 REM RESOLVER POLINOMIO
280 CLS
290 PRINT TAB(23);MID$(OP1$,5)
300 PRINT
310 INPUT "Grado de ecuación polonomica (max 20)              : ",DEG
320 IF DEG<0 OR DEG>MX THEN 300
330 INPUT "Valor de X para el cual debe ser evaluada la ecuación: ",X
340 PRINT
350 FOR I=0 TO DEG
360   PRINT "Coeficiente de X a la potencia";I;
370   INPUT A(I)
380 NEXT I
390 GOSUB 470 : Y1=P
400 PRINT
410 PRINT USING "El valor de la ecuación polinómica para el valor de X = ### es ###.####";X,Y1
420 PRINT : PRINT
430 PRINT "Presione una tecla para continuar...";
440 KY$=INPUT$(1)
450 RETURN
460 REM Sub para encontrar el valor del polinomio en algun valor de x; return P
470 P=A(DEG)
480 FOR I=DEG TO 1 STEP -1
490   P=(A(I-1)+X*P)
500 NEXT I
510 RETURN
520 REM RESOLVER ECUACIÓN DIFERENCIAL
530 CLS
540 PRINT TAB(23);MID$(OP2$,5)
550 PRINT
560 INPUT "Grado de ecuación polinómica (max 20)               : ",DEG
570 IF DEG<0 OR DEG>MX THEN 550
580 INPUT "Valor de XX para el cual la ecuación debe ser evaluada : ",X
590 PRINT
600 FOR I=0 TO DEG
610   PRINT "Coeficiente de X a la potencia";I;
620   INPUT A(I)
630 NEXT I
640 GOSUB 470 : Y1=P
650 GOSUB 720 : DY1=PD
660 PRINT
670 PRINT USING "El valor de la ecuación polinómica para el valor de X = ### es ###.####";X,Y1
680 PRINT USING "El valor de la derivada de la ecuación polinómica en X = ### es ###.###";X,DY1
690 GOSUB 420
700 RETURN
710 REM SUB para encopntrar la derivada en algun valor de X. return PD
720 PD=0 : PS=0
730 FOR I=0 TO DEG
740   PS=X^(DEG-(I+1))
750   D(I)=(DEG-I)*A(DEG-I)*PS
760   PD=PD+D(I)
770 NEXT I
780 RETURN