Tutorial de Ren'Py

Bienvenid@ al Tutorial de Ren'Py. Ren'Py (Renobe Python) es un lenguaje de programación muy parecido a Python, especialmente concebido para la creación de novelas visuales. Estas son historias computarizadas con diálogos, imágenes y sonidos, que pueden contar con interactividad por parte del lector, constituyendo en aventuras con múltiples hilos argumentales.

El propósito de este tutorial es demostrar como hacer un juego en Ren'py en unos pocos pasos.

Antes de empezar a crear un juego, primero hay que tomarse el tiempo de aprender como funciona el Lanzador de Ren'Py. El lanzador te deja crear, gestionar, editar y ejecutar los proyectos de Ren'Py.

Para empezar tendrás que instalar ejecutar el Lanzador de Ren'Py en tu sistema.

Puesto que el lanzador está traducido a varios idiomas, lo primero que deberás hacer es elegir un idioma. Puedes escoger un idioma haciendo clic en Preferencias en la esquina inferior derecha, y eligiendo Español.

Primero deberías ver que apariencia tiene el juego “The Question”. Para verlo, en la primer pantalla seleccioná The Question. Elegí Lanzar Proyecto para ejecutar The Question.

Podés volver a la demo de Ren'Py haciendo lo mismo, pero eligiendo “Tutorial” en lugar de “The Question”.

Vamos a crear un nuevo nuevo proyecto de Ren'Py. En el Lanzador de Ren'Py elegí “Crear Nuevo Proyecto”.

Si esta esa tu primera vez creando un proyecto, Ren'Py te pedirá que elijas un Directorio de proyectos. Este consiste en un directorio (también llamado carpeta) donde se almacenarán los nuevos proyectos, el cual se revisará para buscar proyectos ya existentes. El Selector de Directorios puede aparecer en la parte inferior del Lanzador de Ren'Py, asegurate de revisarlo por si está allí.

Se te solicitará que indiques un nombre de proyecto. Por un nombre bobo, como “Mi Opción”, y apretamos Intro.

Acto seguido el lanzador te pedirá que indiques la resolución del proyecto. 1280×720 es un buen compromiso entre tamaño de juego y calidad de imagen. Para el propósito de este tutorial, le elegimos 1280×720 para que coincida con el arte gráfico del juego “The Question”, y apretamos Continuar.

El lanzador te pedirá luego que escojas un esquema cromático (un color de fondo y de acentos para la interfaz de usuario). En este momento no importa demasiado, elegí algún color lindo, y dale “Continuar”.

Llegado este momento, Ren'Py procesará lo escogido, y creará una plantilla simple para tu juego. La plantilla usa arte y texto “de quita y pon”, pero funcionará, además que te creará automáticamente los botones típicos de retroceder, cargar y guardar jugadas, etcétera.

Para ejecutar la plantilla de tu novela visual, elegí “Lanzar proyecto”.

label start:
 
    "Silvana" "¡Como van! ¿Qué tal estuvo la clase?"
 
    "Yo" "Buena..."
 
    "No puedo admitir que me entró por un oído y me salió por el otro."
 
    "Yo" "¿Te vas a tu casa ahora? ¿Querés que volvamos juntos?"
 
    "Silvana" "¡Dale!"

Este primer guion de juego de Ren'Py sumamente simple. No pusimos ninguna imagen ni música, pero al menos presenta una conversación entre dos personajes, y una de las líneas es una narración en off.

Para probarlo, desde la parte superior de la pantalla seleccioná “My Question”, y luego desde Editar Archivo elegí “script.rpy”. Si es tu primera vez, Ren'Py pedirá que elijas un Editor para trabajar - para los creativos novatos recomendamos Editra - y el programa descargará el editor que elijas. Una vez hecho esto, abrirá el archivo de guion con el editor que pediste.

Ahora bien, una vez que se abra el editor, borrá todo el contenido de script.rpy. Empezaremos desde cero, por lo que no necesitamos nada de lo que ya tiene escrito. Copiá el ejemplo anterior en script.rpy y guardalo.

Ahora estamos listos para ejecutar este guion de ejemplo. Volvemos al Lanzador y elegimos “Lanzar Proyecto”. Ren'Py lo ejecutará. Fijate como Ren'py te dará sin mas, los menús que te dejan cargar y grabar una partida, así como los de modificar las preferencias del juego. Cuando estés listo, apretá “Lanzar Proyecto” y podrás jugar este guion de ejemplo.

El ejemplo incluye - sin embargo - varias declaraciones muy comunes del lenguaje Ren'Py.

La primer línea es una declaración label. La declaración label se usa para etiquetar un lugar en el programa. En este caso, creamos una etiqueta llamada start. La etiqueta start es especial porque determina el lugar donde comenzarán a ejecutarse los guiones de RenPy cuando presiones Empezar Juego en el menú principal.

Las demás líneas son declaraciones say. Existen dos formas de declaración say:

• Una forma usada para narración en off o pensamientos del personaje principal: consiste en una cadena (comienza con comillas “, contiene caracteres, y termina con comillas ”, todo en una sola línea.
• Una forma para diálogos: consiste en dos cadenas; la primer cadena un nombre de personaje y la segunda cadena es lo que dice dicho personaje.

Tené en cuenta que todas las declaraciones say están sangradas 4 espacios. Esto se debe a que existe un bloque debajo de la declaración label. En Ren'Py, los bloques necesariamente deben estar sangrados en relación a la declaración anterior, y todas las declaraciones en un bloque deben estar sangradas por la misma cantidad de caracteres.

En caso que las cadenas en si contengan caracteres de “, estas deben ser escapadas con una barra invertida \. Por ejemplo:

    "Silvana" "¿Alguna vez oíste la famosa frase de Perón, \"El problema con las citas sacadas de Internet, es que muchas de ellas no son genuinas.\"?"

Si bien este guion simple no tiene mucho efectismo, resulta un ejemplo de cuán fácil es lograr algo funcional usando Ren'Py. En breve le agregaremos las imágenes, pero primero veamos cómo se definen los personajes.

Main article: Defining Character Objects

Un problema del primer ejemplo es que hace necesario ingresar repetidamente el nombre de un personaje cada vez que el tipo habla (como si fuese un guion de una obra teatral). Si tuviésemos mucho diálogo en nuestro juego, esto se volverá muy molesto en poco tiempo. Es posible también presentar ambos nombres del personaje de la misma manera, con el color identificativo escogido al iniciar el juego. Para solucionarlo, Ren'Py nos dejará definir los personajes por adelantado. Gracias a ello, podremos asociar un nombre abreviado al personaje, y cambiar el color del nombre del personaje.

define s = Character('Silvana', color="#c8ffc8")
define m = Character('Yo', color="#c8c8ff")
 
label start:
 
    s "¡Como van! ¿Qué tal estuvo la clase?"
 
    m "Buena..."
 
    "No puedo admitir que me entró por un oído y me salió por el otro."
 
    s "¿Te vas a tu casa ahora? ¿Querés que volvamos juntos?"
 
    m "¡Dale!"

La primera y segunda línea definen personajes. La primer línea define un personaje con el nombre abreviado de “s”, y su nombre largo ”Silvana“, con un color de nombre verdoso (los colores se representan con tripletes hexadecimales rojo-verde-azul, como lo hacen en las páginas web).

La segunda línea crea un personaje con el nombre corto ”m“ y el nombre largo ”Yo“. con el color de nombre rojizo. Podés inventar otros personajes copiando una de las líneas de definición de personaje, y cambiándole su nombre corto, nombre largo y el color.

También cambiamos las declaraciones say para usar objetos Character en lugar de una cadena de nombre para un personaje. Esto le permitirá a Ren'Py usar los personajes que le hemos definido.

Main article: Displaying Images

No obtendremos una novela visual si no recurrimos a presentar imágenes en la pantalla. Aquí hay otra escena de “The Question”. Esta también incluye declaraciones que muestran imágenes al jugador. Esto puede reemplazar completamente la sección anterior del guion, si lo deseas probar.

define s = Character('Silvana', color="#c8ffc8")
define m = Character('Yo', color="#c8c8ff")
 
label start:
 
    scene bg meadow
 
    "A poco caminar, alcanzamos los prados justo al lado del vecindario donde vivimos."
 
    "Es una vista muy linda a la que me fui acostumbrando. El otoño es especialmente hermoso por estos lares."
 
    "Cuando éramos chic@s, jugábamos mucho en estos campitos, están llenos de recuerdos."
 
    m "Ey... Umm..."
 
    show sylvie green smile
 
    "Gira hacia mi y sonríe. Parece tan a gusto que siento que mis nervios desaparecen."
 
    "¡Le voy a preguntar...!"
 
    m "Ummm... ¿Serías..."
 
    m "¿Serías mi artista para una novela visual?"
 
    show sylvie green surprised
 
    "Silencio."

Este segmento de guion introduce dos declaraciones nuevas. La declaración scene de la línea 6 borra todas las imágenes y presenta solamente una imagen de fondo. Las declaraciones show de las líneas 16 y 26 hacen aparecer en pantalla un sprite (una gráfica activable) encima de la imagen de fondo, y modifican este sprite, respectivamente.

En Ren'Py, cada imagen consta de un nombre. El nombre consiste de una etiqueta, y opcionalmente de uno o más atributos. Tanto la etiqueta como los atributos deben empezar con una letra, y sólo pueden contener letras, números y guiones bajos. Por ejemplo:

• En la declaración scene de la línea 6, la etiqueta es ”bg“ y el atributo es ”meadow“. Por convención, las imágenes de fondo usan la etiqueta ”bg“ (por “background”, o “fondo” en inglés).
• En la primer declaración show en la línea 16, la etiqueta es ”sylvie“, y los atributos son ”green“ y ”smile“.
• En la segunda declaración show de la línea 26, la etiqueta es ”sylvie“ y los atributos son ”green“ y ”surprised“.

En cada momento dado, sólo puede aparecer una imagen con una etiqueta dada. Si se presenta una segunda imagen del mismo nombre, esta reemplazará a la primera (tal como sucede en la línea 26 del guion).

Ren'Py buscará el fichero de imagen en el directorio de imágenes, que puede localizarse seleccionando “Imagenes” en la sección ”Abrir Directorio“ del Lanzador de Ren'Py. Ren'Py puede usar arte de personajes que se encuentren en formato PNG, WEBP, o AVIF, mientras que el arte de fondo puede estar en formato JPG, JPEG, PNG, WEBP, o AVIF. También existe siporte para archivos SVG, aunque estos se utilizan fundamentalmente para personalizar la interfaz de usuario. Es muy importante el nombre de archivo - puesto que la extensión no se usa, el nombre de archivos se convierte forzadamente a minúsculas, y se emplea el resultado como nombre de la imagen.

Por ejemplo, los siguientes archivos - localizados en el directorio de imágenes - definen las siguientes imágenes:

  "bg meadow.jpg" -> bg meadow

  "sylvie green smile.png" -> sylvie green smile

  "sylvie green surprised.png" -> sylvie green surprised

Puesto que los nombres de archivo están en minúscula, también lo siguiente se mantiene:

  "Sylvie Green Surprised.png" -> sylvie green surprised

Las imágenes también pueden ser colocadas en subdirectorios (subcarpetas) contenidas en el directorio de imágenes. El nombre de directorio resultará ignorado y sólo se usará el nombre de archivo para definir el nombre de imágenes.

Ren'Py también soporta una declaración hide, que oculta una imagen dada.

label irse:
 
    s "¡Me voy a encargar ahora mismo!"
 
    hide sylvie
 
    "..."
 
    m "¡Eso no era a lo que me refería!"

En realidad es bastante raro usar hide. Se puede usar show cuando un personaje cambia de emociones, mientras que scene lo usás para el momento en que todos se van. Sólo necesitás usar hide cuando un personaje abandona la escena, pero el resto de la escena tiene que quedar igual.

A veces, puede que no quieras dejar que Ren'Py defina las imágenes automáticamente por sí mismo. Para esto se usa la declaración image. Debería estar en el nivel superior del fichero (sin sangrado y antes de label start), y puede usarse para mapear un nombre de imagen a un fichero de imagen específico. Por ejemplo

image logo = "renpy logo.png"
image eileen happy = "eileen_happy_blue_dress.png"

La declaración image se ejecuta al tiempo de inicio, antes que label start y el resto del gion del juego que interactúa con el jugador.

La declaración image también puede ser utilizada para llevar a cabo tareas mas complejas, pero esto se tratará aparte.

En el guion anterior, las imágenes aparecen y desaparecen de forma instantánea. Ya que cambiar la locación y hacer que un personaje entre o salga de escena es importante, Ren'Py soporta transiciones, que permiten aplicarse cuando los personajes presentan modificaciones.

Las transiciones modifican lo que se muestra, desde el momento de lo que sucedía al final de la última interacción (diálogo, menú o transición - entre otras declaraciones) hasta la apariencia luego de que se han ejecutado las declaraciones scene, show y hide.

label start:
 
    scene bg meadow
    with fade
 
    "A poco caminar, alcanzamos los prados justo al lado del vecindario donde vivimos."
 
    "Es una vista muy linda a la que me fui acostumbrando. El otoño es especialmente hermoso por estos lares."
 
    "Cuando éramos chicos, jugábamos mucho en estos campitos, están llenos de recuerdos."
 
    m "Ey... Umm..."
 
    show sylvie green smile
    with dissolve
 
    "Gira hacia mi y sonríe. Parece tan a gusto que siento que mis nervios desaparecen."
 
    "¡Le voy a preguntar...!"
 
    m "Ummm... ¿Serías..."
 
    m "¿Serías mi artista para una novela visual?"

La declaración with recibe el nombre de la transición a emplear. La más común es dissolve, que disuelve de una pantalla a la siguiente. Otra transición útil es fade, que desvanece la pantalla a negro, y luego la desvanece a la siguiente pantalla.

Cuando colocás una transición tras múltiples declaraciones scene, show o hide, se aplicará a todas ellas a la vez. Si escribís:

    scene bg meadow
    show sylvie green smile
    with dissolve

Tanto las imágenes ”bg meadow“ y ”sylvie green smile“ se disolverán al mismo tiempo. Para disolver una a la vez, es necesario programarlo usando dos declaraciones with:

    scene bg meadow
    with dissolve
    show sylvie green smile
    with dissolve

Esto primero disuelve el fondo del prado, y luego disuelve a Silvana. Si querías mostrar el prado instantáneamente, y luego presentar a Silvana, podías programarlo así:

    scene bg meadow
    with None
    show sylvie smile
    with dissolve

Aquí se usa None para indicar una transición especial que actualiza la idea de Ren'Py de que era la pantalla anterior, sin mostrarle nada al jugador.

Main article: Transforms

Por defecto, las imágenes se muestran centradas horizontalmente, y con su borde inferior tocando el borde inferior de la pantalla. Esto usualmente está bien para fondos y personajes únicos, pero cuando se muestra más de un personaje en la pantalla, probablemente tenga más sentido hacerlo en otra posición. También puede tener sentido reposicionar un personaje según como venga el relato.

     show sylvie green smile at right

Para hacer este reposicionamiento, agrega una clausula at a la declaración show. La cláusula at recibe una posición, y presenta la imagen en dicha posición. Ren'Py incluye varias posiciones predefinidas: left para el lado izquierdo de la pantalla, right para el lado derecho, center para centrarlo horizontalmente (el valor por defecto) y truecenter para que la centre horizontalmente y verticalmente.

Los creadores puede incluso definir sus propias posiciones, y hacer eventos con movimientos complejos, pero esto cae por fuera de este tutorial rápido

Main article: Audio

La mayoría de los juegos de Ren'Py tienen música de fondo. La música se reproduce con la declaración play music. La declaración play music recibe un nombre de archvio que es interpretado como un fichero de audio que debe ejecutarse. Los ficheros de audio se interpretan en relación al directorio de juevo. Los ficheros de audio deben estar en formato opus, ogg vorbis, o mp3.

Por ejemplo:

    play music "audio/illurock.ogg"

Cuando se cambia la música, uno puede indicar una cláusula fadeout o fadein, que se usan para desvanecer el volúmen de la antigua música y aumentar el volúmen de la música nueva (para hacer una transición suave de músicas).

    play music "audio/illurock.ogg" fadeout 1.0 fadein 1.0

La declaración queue music reproduce un fichero de audio después que el fichero de audio actual terminal

    queue music "audio/next_track.opus"

Podés parar la música con la declaración stop music, que también puede recibir una cláusula fadeout opcional.

    stop music

Los efectos de sonido pueden reproducirse con la declaración play sound. A diferencia de la música, los efectos de sonido no tienen bucle (no se repiten indefenidamente).

    play sound "audio/effect.ogg"

Cuando ponés los archivo de audio en el directorio game/audio, y podés usar el nombre sin extensión de archivo, al estilo de una variable de Python (o sea, comienza con una letra, y contiene sólo letras, números y guiones bajos). En tal caso, te será posible reproducir dicho fichero sin poner las comillas.

Por ejemplo, si tenés el archivo de audio game/audio/illurock.ogg, podés programar:

    play music illurock

La declaración pause hace que Ren'Py haga una pausa hasta hacer clic con el mouse.

    pause

Si le indicás un número, la pausa finalizará sola cuando transcurran dicho número de segundos.

    pause 3.0

Podés finalizar el juego con la declaración return, sin tener que llamar a nada. Antes de hacere esto, es mejor poner algo en el juego que indique que el juego terminó, y tal vez dando un número de finalización o un nombre de finalización al usuario.

    ".:. Final Feliz."
 
    return

Esto es todo lo que tenés que hacer para hacer una novela cinética, un juego sin ningún tipo de opción que seguir en él. Ahora veremos lo que se necesita para hacer que un juego que presente menúes con opciones para que elija el usuario.

Main articles: In-Game Menus and Labels & Control Flow

La declaración menu te permite presentar una opción al jugador:

    s "Seguro, pero ¿qué es una \"novela visual?\""
 
menu:
 
    "Es un videojuego.":
        jump juego
 
    "Es un libro interactivo.":
        jump libro
 
label juego:
 
    m "Es como un videojuego que jugás en la computadora o en una consola."
 
    jump casamiento
 
label libro:
 
    m "Es como un libro interactivo que leés en una computadora o una consola."
 
    jump casamiento
 
label casamiento:
 
    "Y de esta manera, nos volvimos un dúo creador de novelas visuales."

Este ejemplo presenta un menú que puede usarse con Ren'Py. La declaración menu introduce una selección dentro del juego. Requiere un bloque de líneas sangradas, cada una consiste en una cadena seguida por dos puntos (:). Estas serán las opciones del menú, que se le presentarán al jugador. Cada opción del menú requiere su propio bloque de líneas sangradas, que se ejecutan cuando se eligen dicha opción del menú.

En este ejemplo, cada una de las dos opciones del menú ejecuta una única declaración jump. La declaración jump transfiere el control a la etiqueta definida a través de la declaración label. Luego del salto jump, se ejecutan las declaraciones del guion que siguen a la etiqueta label determinada.

En el ejemplo anterior, luego de que Silvana realiza su pregunta, al jugador se le presentará un menú que contiene dos opciones. Si el jugador elige “Es un videojuego”, se ejecuta la primer declaración jump, y Ren'Py saltará a la etiqueta juego. Esto provocará que el Punto de Vista del personaje diga “Es una historia con imágenes y música”, tras lo cual Ren'Py saltará a la etiqueta casamiento.

Si no hay una declaración jump al final del bloque asociado con la etiqueta label, Ren'Py continuará a la siguiente declaración. La última declaración jump aquí es técnicamente innecesaria, pero se la incluye para hacer más claro el flujo del juego.

Pueden definirse las etiquetas label en cualquier archivo de juego que esté en el directorio game, y termine con extensión .rpy. El nombre de archivo no importa en Ren'Py, solamente importan las etiquetas contenidas en el. Podés pensar todos los archivos .rpy como si fuese un único archivo .rpy enorme, en el cual se usan los saltos para transferir el control. Esto te da flexibilidad en la manera en la cual organizás el guión de un juego muy largo.

Main articles: Python Statements and Conditional Statements

Si bien podés hacer algunos juegos simplemente usando las declaraciones ya indicadas, otros juegos requieren almacenar datos y recabarlos luego. Por ejemplo, puede tener sentido que el juego recuerde una opción escogida por el jugador, volver a una sección común del guion, y actuar en la opción más adelante. Esta es una de las razones por la cual Ren'Py tiene soporte de Python incorporado.

Aquí le mostraremos como almacenar un flag que contiene información sobre una opción que el jugador hizo. Para inicializar el flag, se usa la declaración default, antes de la etiqueta label start

# True si el jugador ha decidido comparar las NV con un libro.
default libro = False
 
label start:
 
    s "¡Como van! ¿Qué tal estuvo la clase?"

El flag libro comienza apagada inicializada al valor especial False (como con el resto de Ren'Py, es importante el uso de la mayúscula), lo que significa que no está activada. Si se elige la senda book, podemos ponerla en True usando una declaración de asignación de Python.

label libro:
 
    $ libro = True
 
    m "Es como un libro interactivo que leés en una computadora o una consola."
 
    jump casamiento

Las líneas que comienzan con $ son interpretadas como declaraciones de Python. La declaración de asignación utilizada aquí asigna un valor a una variable. Ren'Py soporta otras formas de incluir Python, tales como las declaraciones multilíneas de Python, que se discuten en otras secciones del manual. Ren'Py soporta Python 2.7, aunque recomendamos escribir Python que corra en Python 2 y Phyton 3.

Para revisar el flag, isamos la declaración if:

if libro:
 
    "Nuestro primer juego se basa en las ideas de Silvana, pero luego se me ocurrieron mis propias historias también."

Si la condición es verdadera, se ejecutará el bloque del guión. Si no lo es, se lo salteará. La declaración if también puede recibir una cláusula else que introduce un bloque de guion que se ejecuta si la condición es falsa.

if libro:
 
    "Nuestro primer juego se basa en las ideas de Silvana, pero luego se me ocurrieron mis propias historias también."
 
else:
 
    "Silvana ayudó con el guion de nuestro primer videojuego."

Las variables de Python no necesitan ser valores simples True/False. Podés usar variables para almacenar el nombre del jugador, los puntajes, o para cualquier otro propósito. Ya que Ren'Py incluye la habilidad de usar todo el lenguaje de programación Python, es posible hacer muchas cosas.

La carpeta game en el proyecto creado incluirá las siguientes carpetas y ficheros:

Una vez que hiciste un juego, existen varias cosas que podés hacer antes de publicarlo:

Se lanzan nuevas versiones de Ren'Py periódicamente en base a correcciones de errores y nuevas funcionalidades. Antes de lanzarlas, querrías hacer clic en Actualizar en el lanzador de Ren'py para bajarte la última versión. También podés bajarte nuevas versiones y ver un listado de cambios en https://www.renpy.org/latest.html.

Raramente los cambios a Ren'Py requieren que hagas cambios en el guion de tu juego. Los cambios incompatibles se listan allí.

Desde la primer página del Lanzador, elegi “Revisar guion (Lint). Esto revisará tu juego en busca de errores potenciales. Ya que algunos de estos errores sólo afectan a usuarios de otras plataformas, es importante entender y usaurlmente corregir todos estos errores, incluso si no te dan problemas en tu computadora.

Desde la primer página del lanzador, elegí “Compilar Distribuciones”. Pasado en la información indicada en option.rpy, el lanzador construirá uno o más ficheros de archivaje que contendrán a tu juego.

Lint no es un substituto para evaluaciones completas. Es tu responsabilidad revisar tu juego antes de publicarlo. Considerá pedirle a tus amigos que te ayuden a testear la beta de tu juego ya que a menudo un probador podrá encontrar problemas que vos no.

Una vez que terminaste el juego y lo probaste, deberíaws postear el archivo generado en una web donde alguien pueda verlo (no tenés que tener tu propio website, https://itch.io hospeda un montón de novelas visuales)

¡Felicitaciones! ¡Publicaste tu primer novela visual!

Podés ver el guion completo de The Question aqui.

Este Tutorial apenas cubre lo básico de lo que es capaz de hacer Ren'Py. Para hacerlo fácil y breve, omitimos muchas funcionalidades que soporta Ren'Py y simplificamos otras, enfocándonos en un conjunto mínimo de funcionalidades necesarias para emprender una novela visual.

Si te interesa aprender mas, aprovechá para leer el Manual de Ren'Py

¡Gracias por escoger el motor de novelas visuales Ren'Py!. ¡Queremos ver lo que creás con él!