¡Esta es una revisión vieja del documento!

# Declara los personajes utilizados en este juego.
define s = Character(_("Sylvie"), color="#c8ffc8")
define y = Character(_("Yo"), color="#c8c8ff")
 
# Esta es una variable que es Verdadera si comparás un NV con un libro, y Falsa
# si hacés lo contrario.
default libro = False
 
# El juego comienza acá.
label start:
 
    # Empieza reproduciendo un tema musical.
    play music "illurock.opus"
 
    scene bg lecturehall
    with fade
 
    "It's only when I hear the sounds of shuffling feet and supplies being put away that I realize that the lecture's over."
 
    "Professor Eileen's lectures are usually interesting, but today I just couldn't concentrate on it."
 
    "I've had a lot of other thoughts on my mind...thoughts that culminate in a question."
 
    "It's a question that I've been meaning to ask a certain someone."
 
    scene bg uni
    with fade
 
    "When we come out of the university, I spot her right away."
 
    show sylvie green normal
    with dissolve
 
    "Conozco a Sylvie desde que éramos niños. Tiene un gran corazón y siempre ha sido buena amiga conmigo."
 
    "Pero recientemente,... quiero algo más."
 
    "Más que solo hablar, más que sólo caminar a casa junt@s cuando termina la clase."
 
    menu:
 
        "Tan pronto como me observa, decido..."
 
        "Preguntarle ahora mismo.":
 
            jump deuna
 
        "Preguntarle más tarde.":
 
            jump despues
 
 
label deuna:
 
    show sylvie green smile
 
    s "Hola todos! Como fue la clase?"
 
    y "Bien..."
 
    "No puedo admitir que todo me entró por un oído y me salió por el otro."
 
    y "Te vas a casa ahora? Querés ir caminando conmigo?"
 
    s "Seguro!"
 
    scene bg meadow
    with fade
 
    "After a short while, we reach the meadows just outside the neighborhood where we both live."
 
    "It's a scenic view I've grown used to. Autumn is especially beautiful here."
 
    "When we were children, we played in these meadows a lot, so they're full of memories."
 
    y "Ey... Umm..."
 
    show sylvie green smile
    with dissolve
 
    "Gira hacia mi y sonríe. Parece tan a gusto que siento que mis nervios desaparecen."
 
    "Le voy a preguntar...!"
 
    y "Ummm... serías..."
 
    y "Serías mi artista para una novela visual?"
 
    show sylvie green surprised
 
    "Silencio."
 
    "Parecía tan shockeada que comencé a temer lo peor. Pero entonces..."
 
    show sylvie green smile
 
    menu:
 
        s "Seguro, pero ¿qué es una \"novela visual?\""
 
        "Es un videojuego.":
            jump juego
 
        "Es un libro interactivo.":
            jump libro
 
 
label juego:
 
    y "Es como un videojuego que jugás en la computadora o en una consola."
 
    y "Las novelas visuales cuentan una historia con imágenes y música."
 
    y "A veces tenés que decidir cosas que afectan el devenir de la historia."
 
    y "Así que es como los libros de elige tu propia aventura?"
 
    y "Exacto! Tengo muchas ideas que podrían funcionar."
 
    y "Y pensé que tal vez podrías ayudarme... ya que sé que te gusta dibujar."
 
    y "Sería difícil para mí hacer una novela visual si dependiera solo de mí."
 
    show sylvie green normal
 
    s "Bueno, claro! puedo probar. Sólo espero no ser un desastre."
 
    y "Vos sabés que nunca me decepcionarías, Sylvie."
 
    jump marry
 
 
label libro:
 
    $ libro = True
 
    y "Es como un libro interactivo que leés en una computadora o una consola."
 
    show sylvie green surprised
 
    s "¿Interactivo?"
 
    y "Podés hacer elecciones que te lleven por distintos eventos y distintos finales de la historia."
 
    s "Y de donde viene lo de \"visual\" en todo esto?"
 
    y "Las novelas visuales tienen imágenes e incluso música, efectos de sonido, y a veces hasta doblaje de voces, que se reproducen a la vez que aparece el texto."
 
    show sylvie green smile
 
    s "Ya veo! Parece bastante divertido. Yo hice webcomics hace mucho, así que tengo muchas ideas para hacer historias."
 
    y "Buenísimo! Así que te interesaría trabajar conmigo como artista?"
 
    s "Me encantaría!"
 
    jump marry
 
label marry:
 
    scene black
    with dissolve
 
    "Y de esta manera, nos volvimos un dúo creador de novelas visuales."
 
    scene bg club
    with dissolve
 
    "Con el pasar de los años, hicimos montones de juegos y nos divertimos mucho haciéndolos."
 
    if libro:
 
        "Nuestro primer juego se basa en las ideas de Sylvie, pero luego se me ocurrieron mis propias historias también."
 
    "Nos turnamos creando nuevas historias y personajes y nos apoyamos mutuamente para hacer los mejores juegos!"
 
    "Y un día..."
 
    show sylvie blue normal
    with dissolve
 
    s "Ey..."
 
    y "¿Si?"
 
    show sylvie blue giggle
 
    s "¿Te casarías conmigo?"
 
    y "¿Qué? ¿De donde sale esto?"
 
    show sylvie blue surprised
 
    s "Dale, ¿cuánto hace que salimos?"
 
    y "Un rato..."
 
    show sylvie blue smile
 
    s "Estos últimos años hicimos novelas visuales junt@s, pasamos tiempo jujnt@s, nos ayudamos entre nosotr@s..."
 
    s "Hemos llegado a conocernos y cuidar de nosotr@s mejor que nadie. Creo que pensás lo mismo, verdad?"
 
    y "Sylvie..."
 
    show sylvie blue giggle
 
    s "Pero yo se que sos indecis@. Si no hago nada, quién sabe cuando lo propondrías?"
 
    show sylvie blue normal
 
    s "Así que te casarías conmigo?"
 
    y "Por supuesto que si! Ya estaba pensando en proponértelo, para ser honest@!"
 
    s "Ya sé, ya sé."
 
    y "Supongo... que estaba muy preocupad@ por el timing. Quería preguntar la pregunta precisa en el momento correcto."
 
    show sylvie blue giggle
 
    s "Te preocupás demasiado. Si solo esto fuese una novela visual y pudiese escoger una opción que sale en un menú, sería más valiente!"
 
    scene black
    with dissolve
 
    "Nos casamos poco después."
 
    "Nuestro duo de novelas visuales continúa después de habernos casado... y yo dí lo mejor de mí para ser más decidid@."
 
    "Junt@s, vivimos felices y comimos perdices veganas."
 
    "{b}Final Feliz!{/b}."
 
    return
 
label despues:
 
    "I can't get up the nerve to ask right now. With a gulp, I decide to ask her later."
 
    scene black
    with dissolve
 
    "Pero soy una persona indecisa."
 
    "No pude preguntarle ese día, y al final nunca pude preguntarle."
 
    "Supongo que jamás sabré la respuesta a mi pregunta..."
 
    "{b}Final horrible!{/b}."
 
    return